|
![](/i/fill.gif) |
I apologize for the sloppyness :)
Image posted in p.b.images
Jay Raney
----------------------------------------------------
// Aqua Pod v2
// copyright Jay Raney
// 2.22.2000
#declare whiteplastic =
texture {
pigment { rgb 1 }
finish { phong 1 phong_size 40 diffuse 1 brilliance .8 }
}
#declare blackplastic =
texture {
pigment { rgb .1 }
finish { phong 1 phong_size 40 diffuse .25 brilliance .8 }
}
#declare chrome =
texture {
pigment { rgb .1 }
finish { phong 1 phong_size 40 reflection .65 }
}
#declare clearglass =
texture {
pigment { rgbf <.92,.93,.95,.94> }
finish { phong 1 phong_size 50 reflection .15 ior 1.2 }
}
#declare yellowenamel =
texture {
pigment { rgb <1,.8,0> }
finish { phong 1 phong_size 90 reflection .2 }
}
#declare yellowplastic =
texture {
pigment { rgb <1,.8,0> }
finish { phong 1 phong_size 40 }
}
#declare marine_green =
texture {
pigment { rgb <.7,.9,.1> }
finish { diffuse 1 brilliance .5 phong 2 phong_size 100 ambient .1}
}
#declare mapsc = 6.8
#declare ap_tex =
texture {
pigment {
image_map {
gif "ap_map.gif"
map_type 0 //planar
interpolate 0 //none
}
scale <mapsc,mapsc*.75,1>
rotate <0,90,0>
translate <0,-2.05,3.4>
}
finish { diffuse 1 brilliance .5 phong 2 phong_size 100 ambient .1}
}
//-----------------------------------------------------------------------------
background { rgb 1 }
camera { location <0,4,-6> look_at <0,2.6,0> rotate <0,90,0> translate
<0,.65,-.25> angle 60 }
global_settings {
radiosity {
brightness 0.3
count 120
error_bound 0.5
recursion_limit 1
}
}
light_source { <-150,170,-100> rgb 1
//area_light <0.0, 15.0, 15.0>, < 15.0, 0.0, 0.0 >, 15, 15
adaptive 1 jitter
}
plane { y,0 pigment { rgb 1 } finish { diffuse 1 brilliance 0 ambient
.4} }
sphere { <0,0,0> 1000
hollow
pigment { gradient y
color_map {
[ 0.0 color rgb <1,1,1> ]
[ 0.5 color rgb <0,.5,1> ]
[ 1 color rgb <0,0,0> ]
}
scale <1,1000,1>
}
finish { brilliance 0 ambient 1 }
}
#default { texture { pigment { rgb <.95,.96,.98> } finish { diffuse .95
brilliance .4 phong 4 phong_size 200 ambient .1 } } }
#declare headlight =
union {
// difference {
// sphere { <0,0,0> 1 scale <1,1,2> rotate <-20,0,0> texture {
marine_green } }
// sphere { <0,0,-1> 1.333 texture { whiteplastic } }
// }
intersection {
difference {
sphere { <0,0,0> 1.05 }
sphere { <0,0,0> 1 }
scale <1,1,2>
rotate <-20,0,0>
}
box { <-2,-2,-.125> <2,2,.125> }
texture { chrome }
}
intersection {
sphere { <0,0,0> 1 scale <1,1,.65> rotate <0,0,0> translate <0,0,0> }
box { <-5,-5,-5> <5,5,.05> }
texture { clearglass }
normal { quilted scale .25 }
}
}
#declare shell =
blob {
threshold 1
sphere { <0,0,0> 3 strength 2 scale <1,.95,2> }
sphere { <0,0,0> 5.7 strength 1 scale <.05,1.5,.25> rotate <45,0,0>
translate <0,3.6,3.7> } // tail fin
sphere { <0,0,0> 1.5 strength .8 scale <.05,1.5,.35> rotate <40,0,0>
translate <0,1.25,-.5> }
sphere { <0,0,0> .58 strength -.7 scale <2,1.8,.7> rotate <-18,0,0>
translate <0,1.1,2.2> } // prop hole
sphere { <0,0,0> .4 strength -.6 scale <1,1.2,.7> rotate <-9,0,0>
translate <0,1.7,2.6> }
sphere { <0,0,0> 2 strength -1 translate <0,-1.8,2> }
sphere { <0,0,0> 1 strength -2 scale <2,1,2> translate <0,1,-2> }
sphere { <0,0,0> 1 strength 2 scale <1,.25,1.6> rotate <-10,-20,0>
scale <2,1,1> translate <-1.8,0,.25> } // wing
sphere { <0,0,0> 1 strength 2 scale <1,.25,1.6> rotate <-10,20,0> scale
<2,1,1> translate <1.8,0,.25> } // wing
sphere { <0,0,0> .5 strength .4 scale <1,.15,.75> rotate <-4,0,0> scale
<2,1,1> translate <0,1.7,-.1> } // stabilizer
sphere { <0,0,0> 3 strength -.6 scale <2,.5,.7> rotate <-15,0,0>
translate <0,-.75,2> }
sphere { <0,0,0> 3 strength -.3 scale <.4,.2,.5> rotate <-60,-10,-10>
scale <1,.5,1> translate <-1.5,1.1,.2> } // side window
sphere { <0,0,0> 3 strength -.3 scale <.4,.2,.5> rotate <-60,10,10>
scale <1,.5,1> translate <1.5,1.1,.2> } // side window
sphere { <0,0,0> .4 strength .125 scale <.8,1,.75> rotate <0,-25,0>
translate <-.5,-.2,-3.2> } // headlight
sphere { <0,0,0> .4 strength .125 scale <.8,1,.75> rotate <0,25,0>
translate <.5,-.2,-3.2> } // headlight
sphere { <0,0,0> .5 strength -.02 scale <.25,.1,1.75> rotate
<0,-25,-12> translate <-1.13,0,-2.2> }
sphere { <0,0,0> .5 strength -.02 scale <.25,.1,1.75> rotate
<0,-25,-12> translate <-1.14,-.1,-2.2> }
sphere { <0,0,0> .5 strength -.02 scale <.25,.1,1.75> rotate
<0,-25,-12> translate <-1.15,-.2,-2.2> }
sphere { <0,0,0> .5 strength -.02 scale <.25,.1,1.75> rotate
<0,-25,-12> translate <-1.16,-.3,-2.2> }
sphere { <0,0,0> .5 strength -.02 scale <.25,.1,1.75> rotate
<0,-25,-12> translate <-1.17,-.4,-2.2> }
sturm
}
#declare trim =
blob {
threshold 1
sphere { <0,0,0> 3 strength 2 scale <1,.95,2> }
sphere { <0,0,0> .998 strength -2 scale <2,1,2> translate <0,1,-2> }
sphere { <0,0,0> 2.988 strength -.295 scale <.4,.2,.5> rotate
<-60,-10,-10> scale <1,.5,1> translate <-1.5,1.1,.2> } // side window
sphere { <0,0,0> 2.988 strength -.295 scale <.4,.2,.5> rotate
<-60,10,10> scale <1,.5,1> translate <1.5,1.1,.2> } // side window
scale .999
clipped_by {
box { <-4,.1,-4> <4,4,.8> }
}
}
#declare prop =
blob {
threshold 1
sphere { <0,0,0> 4 strength 3 scale <.04,.2,.5> rotate <0,0,30> }
sphere { <0,0,0> .75 strength -4 scale <1,1,4> rotate <-20,20,0>
translate <-.45,.25,.5> }
sphere { <0,0,0> .5 strength -1.5 scale <1,1,2> rotate <-40,0,0>
translate <0,.125,-.65> }
sphere { <0,0,0> .5 strength -2 scale <1,1,2> rotate <-40,0,0>
translate <0,-.35,.75> }
rotate <0,0,6>
translate <0,0,-.6>
}
#declare prop =
union {
object { prop rotate <0,0,0> }
object { prop rotate <90,0,0> }
object { prop rotate <180,0,0> }
object { prop rotate <270,0,0> }
sphere { <0,0,0> .18 scale <4,1,1> }
rotate <0,90,0>
rotate <0,0,15>
}
#declare aquapod =
union {
difference {
object { shell texture { ap_tex } }
sphere { <0,0,-1> .333 texture { whiteplastic } translate
<-.5,-.2,-2.4> }
sphere { <0,0,-1> .333 texture { whiteplastic } translate
<.5,-.2,-2.4> }
}
object { trim texture { blackplastic } }
object { headlight scale .218 rotate <-10,12,0> translate
<-.42,-.17,-3.18> }
object { headlight scale .218 rotate <-10,-12,0> translate
<.42,-.17,-3.18> }
difference {
sphere { <0,0,0> 1.55 scale <1,.95,2> pigment { rgbf<.5,.6,.8,.9> }
finish { reflection .35 specular .8 roughness .001 } clipped_by { sphere
{ <0,0,0> 1.5 scale <1,1,2> translate <0,.75,-1> } } }
sphere { <0,0,0> 1.54 scale <1,.95,2> pigment { rgbf<.5,.6,.8,.9> }
finish { reflection .35 specular .8 roughness .001 } hollow }
}
object { prop texture { chrome } scale .35 rotate <-20,0,0> translate
<0,1.07,2.32> }
}
object { aquapod rotate <0,0,0> translate <0,3,0> }
Post a reply to this message
|
![](/i/fill.gif) |